Go to the previous, next section.
GNU Emacs Lisp has convenient on-line help facilities, most of which derive their information from the documentation strings associated with functions and variables. This chapter describes how to write good documentation strings for your Lisp programs, as well as how to write programs to access documentation.
Note that the documentation strings for Emacs are not the same thing as the Emacs manual. Manuals have their own source files, written in the Texinfo language; documentation strings are specified in the definitions of the functions and variables they apply to. A collection of documentation strings is not sufficient as a manual because a good manual is not organized in that fashion; it is organized in terms of topics of discussion.
A documentation string is written using the Lisp syntax for strings, with double-quote characters surrounding the text of the string. This is because it really is a Lisp string object. The string serves as documentation when it is written in the proper place in the definition of a function or variable. In a function definition, the documentation string follows the argument list. In a variable definition, the documentation string follows the initial value of the variable.
When you write a documentation string, make the first line a complete
sentence (or two complete sentences) since some commands, such as
apropos, print only the first line of a multi-line documentation
string. Also, you should not indent the second line of a documentation
string, if you have one, because that looks odd when you use C-h f
(describe-function) or C-h v (describe-variable).
Documentation strings may contain several special substrings, which stand for key bindings to be looked up in the current keymaps when the documentation is displayed. This allows documentation strings to refer to the keys for related commands and be accurate even when a user rearranges the key bindings. (See section Access to Documentation Strings.)
Within the Lisp world, a documentation string is kept with the function or variable that it describes:
documentation knows how to extract it.
variable-documentation. The
function documentation-property knows how to extract it.
However, to save space, the documentation for preloaded functions and
variables (including primitive functions and autoloaded functions) are
stored in the `emacs/etc/DOC-version' file. The
`emacs/etc/DOC-version' file can be accessed by both the
documentation and the documentation-property functions,
and the process is transparent to the user. In this case, the
documentation string is replaced with an integer offset into the
`emacs/etc/DOC-version' file. Keeping the documentation
strings out of the Emacs core image saves a significant amount of space.
See section Building Emacs.
For information on the uses of documentation strings, see section 'Help' in The GNU Emacs Manual.
The `emacs/etc' directory contains two utilities that you can use to print nice-looking hardcopy for the file `emacs/etc/DOC-version'. These are `sorted-doc.c' and `digest-doc.c'.
{Function} documentation-property symbol property &optional verbatim
This function returns the documentation string that is recorded
symbol's property list under property property. This uses
the function get, but does more than that: it also retrieves the
string from the file `emacs/etc/DOC-version' if necessary,
and runs substitute-command-keys to substitute the actual
(current) key bindings.
If verbatim is non-nil, that inhibits running
substitute-command-keys. (The verbatim argument exists
only as of Emacs 19.)
(documentation-property 'command-line-processed
'variable-documentation)
=> "t once command line has been processed"
(symbol-plist 'command-line-processed)
=> (variable-documentation 188902)
{Function} documentation function &optional verbatim
This function returns the documentation string of function. This function will access the documentation string if it is stored in the `emacs/etc/DOC-version' file.
In addition, documentation runs substitute-command-keys
on the resulting string, so the value contains the actual (current) key
bindings. (This is not done if verbatim is non-nil; the
verbatim argument exists only as of Emacs 19.)
The function documentation signals a void-function error
unless function has a function definition. However,
function does not need to have a documentation string. If there
is no documentation string, documentation returns nil.
Here is an example of using the two functions, documentation and
documentation-property, to display the documentation strings for
several symbols in a `*Help*' buffer.
(defun describe-symbols (pattern)
"Describe the Emacs Lisp symbols matching PATTERN.
All symbols that have PATTERN in their name are described
in the `*Help*' buffer."
(interactive "sDescribe symbols matching: ")
(let ((describe-func
(function
(lambda (s)
;; Print description of symbol.
(if (fboundp s) ; It is a function.
(princ
(format "%s\t%s\n%s\n\n" s
(if (commandp s)
(let ((keys (where-is-internal s)))
(if keys
(concat
"Keys: "
(mapconcat 'key-description
keys " "))
"Keys: none"))
"Function")
(or (documentation s)
"not documented"))))
(if (boundp s) ; It is a variable.
(princ
(format "%s\t%s\n%s\n\n" s
(if (user-variable-p s)
"Option " "Variable")
(or (documentation-property
s 'variable-documentation)
"not documented")))))))
sym-list)
;; Build a list of symbols that match pattern.
(mapatoms (function
(lambda (sym)
(if (string-match pattern (symbol-name sym))
(setq sym-list (cons sym sym-list))))))
;; Display the data.
(with-output-to-temp-buffer "*Help*"
(mapcar describe-func (sort sym-list 'string<))
(print-help-return-message))))
The describe-symbols function works like apropos,
but provides more information.
(describe-symbols "goal") ---------- Buffer: *Help* ---------- goal-column Option *Semipermanent goal column for vertical motion, as set by C-x C-n, or nil. set-goal-column Command: C-x C-n Set the current horizontal position as a goal for C-n and C-p. Those commands will move to this position in the line moved to rather than trying to keep the same horizontal position. With a non-nil argument, clears out the goal column so that C-n and C-p resume vertical motion. The goal column is stored in the variable `goal-column'. temporary-goal-column Variable Current goal column for vertical motion. It is the column where point was at the start of current run of vertical motion commands. When the `track-eol' feature is doing its job, the value is 9999. ---------- Buffer: *Help* ----------
{Function} Snarf-documentation filename
This function is used only during Emacs initialization, just before the runnable Emacs is dumped. It finds the file offsets of the documentation strings stored in the file filename, and records them in the in-core function definitions and variable property lists in place of the actual strings. See section Building Emacs.
Emacs finds the file filename in the `emacs/etc'
directory. When the dumped Emacs is later executed, the same file is
found in the directory data-directory. Usually filename is
"DOC-version".
{Variable} data-directory
This variable holds the name of the directory in which Emacs finds
certain data files that come with Emacs or are built as part of building
Emacs. (In older Emacs versions, this directory was the same as
exec-directory.)
This function makes it possible for you to write a documentation string
that enables a user to display information about the current, actual key
bindings. if you call documentation with non-nil
verbatim, you might later call this function to do the
substitution that you prevented documentation from doing.
{Function} substitute-command-keys string
This function returns string with certain special substrings replaced by the actual (current) key bindings. This permits the documentation to be displayed with accurate information about key bindings. (The key bindings may be changed by the user between the time Emacs is built and the time that the documentation is asked for.)
This table lists the forms of the special substrings and what they are replaced with:
\[command]
\{mapvar 2
describe-bindings.)
\<mapvar>
substitute-command-keys use the value of
mapvar as the keymap for future `\[command]'
substrings. This special string does not produce any replacement text
itself; it only affects the replacements done later.
Please note: each `\' must be doubled when written in a string in Emacs Lisp.
Here are examples of the special substrings:
(substitute-command-keys
"To abort recursive edit, type: \\[abort-recursive-edit]")
=> "To abort recursive edit, type: C-]"
(substitute-command-keys
"The keys that are defined for the minibuffer here are:
\\{minibuffer-local-must-match-map 2")
=> "The keys that are defined for the minibuffer here are:
? minibuffer-completion-help
SPC minibuffer-complete-word
TAB minibuffer-complete
LFD minibuffer-complete-and-exit
RET minibuffer-complete-and-exit
C-g abort-recursive-edit
"
(substitute-command-keys
"To abort a recursive edit from the minibuffer, type\
\\<minibuffer-local-must-match-map>\\[abort-recursive-edit].")
=> "To abort a recursive edit from the minibuffer, type C-g."
These functions convert events, key sequences or characters to textual descriptions. These descriptions are useful for including arbitrary text characters or key sequences in messages, because they convert non-printing characters to sequences of printing characters. The description of a printing character is the character itself.
{Function} key-description sequence
This function returns a string containing the Emacs standard notation
for the input events in sequence. The argument sequence may
be a string, vector or list. See section Input Events, for more information
about valid events. See also the examples for
single-key-description, below.
{Function} single-key-description event
This function returns a string describing event in the standard Emacs notation for keyboard input. A normal printing character is represented by itself, but a control character turns into a string starting with `C-', a meta character turns into a string starting with `M-', and space, linefeed, etc. are transformed to `SPC', `LFD', etc. A function key is represented by its name. An event which is a list is represented by the name of the symbol in the CAR of the list.
(single-key-description ?\C-x)
=> "C-x"
(key-description "\C-x \M-y \n \t \r \f123")
=> "C-x SPC M-y SPC LFD SPC TAB SPC RET SPC C-l 1 2 3"
(single-key-description 'C-mouse-1)
=> "C-mouse-1"
{Function} text-char-description character
This function returns a string describing character in the
standard Emacs notation for characters that appear in text--like
single-key-description, except that control characters are
represented with a leading caret (which is how control characters in
Emacs buffers are usually displayed).
(text-char-description ?\C-c)
=> "^C"
(text-char-description ?\M-m)
=> "M-m"
(text-char-description ?\C-\M-m)
=> "M-^M"
Emacs provides a variety of on-line help functions, all accessible to the user as subcommands of the prefix C-h. For more information about them, see section 'Help' in The GNU Emacs Manual. Here we describe some program-level interfaces to the same information.
{Command} apropos regexp &optional do-all predicate
This function finds all symbols whose names contain a match for the regular expression regexp, and returns a list of them. It also displays the symbols in a buffer named `*Help*', each with a one-line description.
If do-all is non-nil, then apropos also shows
key bindings for the functions that are found.
If predicate is non-nil, it should be a function to be
called on each symbol that has matched regexp. Only symbols for
which predicate returns a non-nil value are listed or
displayed.
In the first of the following examples, apropos finds all the
symbols with names containing `exec'. In the second example, it
finds and returns only those symbols that are also commands.
(We don't show the output that results in the `*Help*' buffer.)
(apropos "exec")
=> (Buffer-menu-execute command-execute exec-directory
exec-path execute-extended-command execute-kbd-macro
executing-kbd-macro executing-macro)
(apropos "exec" nil 'commandp)
=> (Buffer-menu-execute execute-extended-command)
The command C-h a (command-apropos) calls apropos,
but specifies a predicate to restrict the output to symbols that
are commands. The call to apropos looks like this:
(apropos string t 'commandp)
{Command} super-apropos regexp &optional do-all
This function differs from apropos in that it searches
documentation strings as well as symbol names for matches for
regexp. By default, it searches only the documentation strings,
and only those of functions and variables that are included in Emacs
when it is dumped. If do-all is non-nil, it scans the
names and documentation strings of all functions and variables.
{Command} help-command
This command is not a function, but rather a symbol which is
equivalent to the keymap called help-map. It is defined in
`help.el' as follows:
(define-key global-map "\C-h" 'help-command) (fset 'help-command help-map)
{Variable} help-map
The value of this variable is a local keymap for characters following the Help key, C-h.
{Function} print-help-return-message &optional function
This function builds a string which is a message explaining how to
restore the previous state of the windows after a help command. After
building the message, it applies function to it if function
is non-nil. Otherwise it calls message to display it in
the echo area.
This function expects to be called inside a
with-output-to-temp-buffer special form, and expects
standard-output to have the value bound by that special form.
For an example of its use, see the example in the section describing the
documentation function (see section Access to Documentation Strings).
The constructed message will have one of the forms shown below.
---------- Echo Area ---------- Type C-x 1 to remove help window. ---------- Echo Area ---------- ---------- Echo Area ---------- Type C-x 4 b RET to restore old contents of help window. ---------- Echo Area ----------
{Variable} help-char
The value of this variable is the character that Emacs recognizes as
meaning Help. When Emacs reads this character (which is usually 8, the
value of C-h), Emacs evaluates (eval help-form), and
displays the result if it is a string. If help-form's value is
nil, this character is read normally.
{Variable} help-form
The value of this variable is a form to execute when the character
help-char is read. If the form returns a string, that string is
displayed. If help-form is nil, then the help character
is not recognized.
Entry to the minibuffer binds this variable to the value of
minibuffer-help-form.
{Variable} prefix-help-command
This variable holds a command that prints help for a prefix character.
The command is run when the user types the help character after a prefix
character. The default value of prefix-help-command is
describe-prefix-bindings; that command uses
this-command-keys to find what prefix character was used, then
uses describe-bindings to describe it.
The following two functions are found in the library `helper'.
They are for modes that want to provide help without relinquishing
control, such as the "electric" modes. You must load that library
with (require 'helper) in order to use them. Their names begin
with `Helper' to distinguish them from the ordinary help functions.
{Command} Helper-describe-bindings
This command pops up a window displaying a help buffer containing a
listing of all of the key bindings from both the local and global keymaps.
It works by calling describe-bindings.
{Command} Helper-help
This command provides help for the current mode. It prompts the user
in the minibuffer with the message `Help (Type ? for further
options)', and then provides assistance in finding out what the key
bindings are, and what the mode is intended for. It returns nil.
This can be customized by changing the map Helper-help-map.
Go to the previous, next section.